<%
Function sanitizeRequest (requestVariable,requestType) 
        Set regEx = New RegExp 
        regEx.Global = true 
        regEx.Pattern = "[^0-9a-zA-Z\@\w\.\,\-\_\$\!\|\:\b\r\ \-]"
        IF requestType = "querystring" THEN 
                sanitizeRequest = regEx.Replace(request.querystring(requestVariable), "") 
        ELSEIF requestType = "form" THEN 
                sanitizeRequest = regEx.Replace(request.form(requestVariable), "") 
        ELSEIF requestType = "cookie" THEN 
                sanitizeRequest = regEx.Replace(request.cookies(requestVariable), "")
        ELSEIF requestType = "string" THEN
                sanitizeRequest = regEx.Replace(requestVariable, "")
        END IF 
End Function

Function PCase(strInput)
	Dim arrWords
	Dim intWord
	arrWords = Split(strInput, " ")
	For intWord = LBound(arrWords) To UBound(arrWords)
		arrWords(intWord) = UCase(Left(arrWords(intWord), 1)) _
		                    & LCase(Mid(arrWords(intWord), 2))
	Next
	PCase = Join(arrWords, " ")
End Function

Function generatePassword(passwordLength)
	'Declare variables
	Dim sDefaultChars
	Dim iCounter
	Dim sMyPassword
	Dim iPickedChar
	Dim iDefaultCharactersLength
	Dim iPasswordLength
	'Initialize variables
	sDefaultChars="-abcdefghijklmnopqrstuvxyz.!ABCDEFGHIJKLMNOPQRSTUVXYZ.!0123456789"
	iPasswordLength=passwordLength
	iDefaultCharactersLength = Len(sDefaultChars) 
	Randomize'initialize the random number generator
	'Loop for the number of characters password is to have
	For iCounter = 1 To iPasswordLength
	'Next pick a number from 1 to length of character set 
	iPickedChar = Int((iDefaultCharactersLength * Rnd) + 1) 
	'Next pick a character from the character set using the random number iPickedChar
	'and Mid function
	sMyPassword = sMyPassword & Mid(sDefaultChars,iPickedChar,1)
	Next 
	generatePassword = sMyPassword
End Function 


Function fmtPostCode(vPC)
'formats postcode with space ie. SE11 1AS
	IF vPC <> "" THEN
		Set regEx = New RegExp 
        regEx.Global = true 
        regEx.Pattern = "[^0-9a-zA-Z\w]"
        vPC = regEx.Replace(vPC,"")
		fmtPostCode = vPC
		vpc_pt1 = left(vPC,len(vPC)-3)
		vpc_pt2 = right(vPC,3)
		fmtPostCode = UCase(vpc_pt1) & " " & UCase(vpc_pt2)
	ELSE
		fmtPostCode = ""
		Exit Function
	END IF
End Function


Function nCast(oVal,dp)
	IF oVal <> "" THEN
		oVal=trim(oVal)
	ELSE
		Exit Function
	END IF
	IF oVal <> "" AND IsNumeric(oVal) THEN
		nCast=formatNumber(oVal,dp)
	ELSE
		nCast=0.00
	END IF 
End Function


Function LPad(rVal)
	padchar = 8 
	padlength = padchar - Len(rVal)
	IF padlength > 0 THEN
		padstring = ""
		for x = 1 to padlength
		 padstring = padstring & "0"
		next
	END IF
	Lpad = padstring & rVal
End Function

Function sendMailMessage(mTo,mFrom,mSub,mContent)
	IF mTo <> "" AND mFrom <> "" AND mSub <> "" AND mContent <> "" THEN
		Dim mobjCDO, mbody
		Set mobjCDO=Server.CreateObject("CDO.Message")
		mobjCDO.To=mTo
		mobjCDO.From="web-server@zywpeit.com"
		mobjCDO.Subject=mSub
		mobjCDO.HTMLBody=mContent
		
		'local
        mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
        mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")="127.0.0.1"
        mobjCDO.Configuration.Fields.Update

        'remote
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.office365.com"
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "web-server@zywpeit.com"
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "hkt348g!h349gKfz3b"
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
        'mobjCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
        'mobjCDO.Configuration.Fields.Update

				
		mobjCDO.Send()
		sendMailMessage="SENT"
	ELSE
		sendMailMessage="FAILED"
	END IF
End Function

%>